Delphi Региональные настройки и TFormatSettings

Часто региональные настройки систем пользователей отличаются, при том что все они в одном языковом регионе. При этом в Delphi по-умолчанию используются настройки системы при загрузке региональных параметров.
Чтобы принудительно загружать из системы настройки нужного языка необходимо до инициализации модуля SysUtils вызвать SetThreadLocale($0419); (для русской языка)
Для этого можно создать модуль, например так:

unit Locale;
interface
implementation
uses
  Windows;
initialization
  SetThreadLocale($0419);
end.

И включить его в файл проекта первым модулем (Для продвинутых кодеров до первого обращения к SysUtils).
Проверить результат можно так:

Caption := FormatDateTime(LongDateFormat + ' ' + LongTimeFormat, Now);

P.S.: Пока писал эту заметку заметил баг в SysUtils.TFormatSettings.TranslateDateFormat.FixDateSeparator (код от XE2) =)
в этой процедуре происходит подмена разделителя дат на слэш '/'
в моем случае разделитель дат точка '.', длинный формат даты 'd MMMM yyyy ''г.'''
в итоге получаю '19 Январь 2013 г/' - забавно
Скорее всего функция должна игнорировать текст в кавычках.
Баг уже зарегистрирован в QС

Delphi Оптимальная локализация приложений

При разработке на Delphi часто приходится писать программы для использования в одном языковом регионе, т.е. для пользователей которым нужен только один язык в программе.
Есть разные методы локализации, в том числе подмена указателей в PResStringRec. Этот способ плох лишним использованием памяти и дополнительными действиями в runtime - фактически нелокализованные строки остаются в модуле и никогда не используются.
Оптимальным же способом локализации является подмена модулей с переводом содержащихся в них строк. Например, можно взять стандартный модуль RTLConsts.pas скопировать его в папку проекта и перевести содержимое. В таком случае перевод будет скомпилирован и прилинкован к модулю.

Подмену указателей можно использовать для временной подмены строк. Например, для отображения диалога с нестандартым текстом кнопок. Для этого надо переделать процедуру HookResourceString в функцию:

function HookResourceString(ResStringRec: PResStringRec;
  NewStr: PChar): PChar;
var
  OldProtect: DWORD;
begin
  VirtualProtect(ResStringRec, SizeOf(ResStringRec^),
    PAGE_EXECUTE_READWRITE, @OldProtect);
  Result := PChar(ResStringRec^.Identifier);
  ResStringRec^.Identifier := Integer(NewStr);
  VirtualProtect(ResStringRec, SizeOf(ResStringRec^),
    OldProtect, @OldProtect);
end;

Сам код временной подмены:

const
  sAccept: PChar = '&Accept';
  sDecline: PChar = '&Decline';
var
  SaveYes: PChar;
  SaveNo: PChar;
begin
  SaveYes := HookResourceString(@SMsgDlgYes, sAccept);
  SaveNo := HookResourceString(@SMsgDlgNo, sDecline);
  MessageDlg('Do you accept terms?', mtConfirmation, mbYesNo, 0);
  HookResourceString(@SMsgDlgYes, SaveYes);
  HookResourceString(@SMsgDlgNo, SaveNo);
  MessageDlg('Do you accept terms?', mtConfirmation, mbYesNo, 0);
end;

Delphi HInstance

Глобальная переменная SysInit.HInstance инициализируется для exe модуля в SysInit._InitExe вызовом HInstance := GetModuleHandle(nil)

Фактически значение данной переменной - это указатель на адрес в памяти по которому загружен PE модуль.

Используя этот адрес можно, например, получить дату сборки проекта, получив прямой доступ к PE заголовку файла в памяти:

function GetLinkDate: TDateTime;
begin
  Result := FileDateToDateTime
    (PInteger(
      PImageNtHeaders(
        Cardinal(PImageDosHeader(HInstance)._lfanew) +  HInstance)^
    .OptionalHeader.DataDirectory[IMAGE_DIRECTORY_ENTRY_RESOURCE]
    .VirtualAddress + HInstance + 4
    )^);
end;